financier-nix/flake.nix

{
  inputs.flake-utils.url = "github:numtide/flake-utils";
  inputs.financier = {
    url = "git+https://codeberg.org/puppe/financier.git?ref=mpuppe";
    flake = false;
  };

  outputs = inputs@{ self, nixpkgs, ... }:
    let
      financierVersion = (builtins.fromJSON
        (builtins.readFile "${inputs.financier}/package.json")).version;
      nodeVersion = "12";

      overlay = final: prev: {
        financier-dist = import ./dist.nix {
          inherit financierVersion;
          inherit (prev) pkgs system;
        };
      };
    in inputs.flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ overlay ];
        };
      in {
        packages = { inherit (pkgs) financier-dist; };
        defaultPackage = self.packages.${system}.financier-dist;
        devShell = pkgs.mkShell {
          packages = with pkgs; [ nodePackages.node2nix ];
          shellHook = ''
            export FINANCIER_SRC="${inputs.financier}"
            export FINANCIER_NODE_VERSION="${nodeVersion}"
          '';
        };
      }) // {
        inherit overlay;
        nixosModule = {
          imports = [ ./module.nix ];
          nixpkgs.overlays = [ self.overlay ];
        };
      };
}